Andrew Kesterson
4daa411f3f
All checks were successful
libakerror CI Build / cmake_build (push) Successful in 2m42s
Add 11 CTest programs and a shared test helper covering gaps left by the original four tests (which only exercised FAIL/CATCH/HANDLE and CLEANUP): - err_capture.h: capturing akerr_log_method + NDEBUG-proof AKERR_CHECK so tests can assert on message/status/stacktrace content, not just exit codes - err_success: clean nested return does not break/handle/leak - err_pool_refcount: 100k raise->catch->handle cycles leak 0 pool slots - err_handle_default / err_handle_group / err_handle_dispatch: handler routing - err_pass / err_ignore / err_swallow: PASS, IGNORE, FINISH(e,false) - err_break_variants: FAIL_*_BREAK and FAIL_*_RETURN - err_errno: system errno name lookup + "Unknown Error" boundary - err_custom_handler: override the unhandled-error hook, assert non-fatally Register tests via a foreach loop in CMakeLists.txt. Ignore build/. Co-Authored-By: Claude Opus 4.8 (1M context) <noreply@anthropic.com>
120 lines
3.2 KiB
CMake
120 lines
3.2 KiB
CMake
cmake_minimum_required(VERSION 3.10)
|
|
project(akerror LANGUAGES C)
|
|
|
|
include(GNUInstallDirs)
|
|
include(CMakePackageConfigHelpers)
|
|
include(CTest)
|
|
|
|
set(AKERR_USE_STDLIB 1 CACHE BOOL "Use the C standard library")
|
|
set(akerror_install_cmakedir "${CMAKE_INSTALL_LIBDIR}/cmake/akerror")
|
|
|
|
set(SCRIPT ${CMAKE_CURRENT_SOURCE_DIR}/scripts/generrno.sh)
|
|
set(INFILE ${CMAKE_CURRENT_SOURCE_DIR}/include/akerror.tmpl.h)
|
|
|
|
set(GENERATED_DIR ${CMAKE_CURRENT_BINARY_DIR}/generated)
|
|
|
|
set(GENERATED_ERRNO_C ${GENERATED_DIR}/src/errno.c)
|
|
set(GENERATED_AKERROR_H ${GENERATED_DIR}/include/akerror.h)
|
|
|
|
add_custom_command(
|
|
OUTPUT ${GENERATED_ERRNO_C} ${GENERATED_AKERROR_H}
|
|
COMMAND ${CMAKE_COMMAND} -E make_directory ${GENERATED_DIR}
|
|
COMMAND /usr/bin/env bash
|
|
${SCRIPT}
|
|
${CMAKE_CURRENT_SOURCE_DIR}
|
|
${GENERATED_DIR}
|
|
DEPENDS ${SCRIPT} ${INFILE}
|
|
VERBATIM
|
|
)
|
|
|
|
add_library(akerror SHARED
|
|
src/error.c
|
|
${GENERATED_ERRNO_C}
|
|
)
|
|
|
|
target_include_directories(akerror PUBLIC
|
|
$<BUILD_INTERFACE:${GENERATED_DIR}/include>
|
|
$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
|
|
)
|
|
|
|
find_package(PkgConfig REQUIRED)
|
|
add_library(akerror::akerror ALIAS akerror)
|
|
|
|
target_compile_definitions(akerror
|
|
PUBLIC AKERR_USE_STDLIB=${AKERR_USE_STDLIB}
|
|
)
|
|
|
|
# Each test is one source file in tests/ built into test_<name> and registered
|
|
# as CTest <name>. Tests expected to abort (unhandled error / contract
|
|
# violation) go in AKERR_WILL_FAIL_TESTS; all others must exit 0.
|
|
set(AKERR_TESTS
|
|
err_catch
|
|
err_cleanup
|
|
err_trace
|
|
err_improper_closure
|
|
err_success
|
|
err_pool_refcount
|
|
err_handle_default
|
|
err_handle_group
|
|
err_handle_dispatch
|
|
err_pass
|
|
err_ignore
|
|
err_swallow
|
|
err_errno
|
|
err_break_variants
|
|
err_custom_handler
|
|
)
|
|
|
|
set(AKERR_WILL_FAIL_TESTS
|
|
err_trace
|
|
err_improper_closure
|
|
)
|
|
|
|
foreach(_test IN LISTS AKERR_TESTS)
|
|
add_executable(test_${_test} tests/${_test}.c)
|
|
target_include_directories(test_${_test} PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/tests)
|
|
target_link_libraries(test_${_test} PRIVATE akerror)
|
|
add_test(NAME ${_test} COMMAND test_${_test})
|
|
endforeach()
|
|
|
|
set_tests_properties(
|
|
${AKERR_WILL_FAIL_TESTS}
|
|
PROPERTIES WILL_FAIL TRUE
|
|
)
|
|
|
|
set(main_lib_dest "lib/my_library-${MY_LIBRARY_VERSION}")
|
|
install(TARGETS akerror
|
|
EXPORT akerrorTargets
|
|
ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
|
|
LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
|
|
RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
|
|
INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
|
|
)
|
|
|
|
install(FILES ${GENERATED_AKERROR_H} DESTINATION "include/")
|
|
install(FILES ${CMAKE_CURRENT_BINARY_DIR}/akerror.pc DESTINATION "lib/pkgconfig/")
|
|
|
|
install(EXPORT akerrorTargets
|
|
FILE akerrorTargets.cmake
|
|
NAMESPACE akerror::
|
|
DESTINATION ${akerror_install_cmakedir}
|
|
)
|
|
|
|
configure_package_config_file(
|
|
cmake/akerror.cmake.in
|
|
"${CMAKE_CURRENT_BINARY_DIR}/akerrorConfig.cmake"
|
|
INSTALL_DESTINATION ${akerror_install_cmakedir}
|
|
)
|
|
|
|
install(FILES
|
|
"${CMAKE_CURRENT_BINARY_DIR}/akerrorConfig.cmake"
|
|
DESTINATION ${akerror_install_cmakedir}
|
|
)
|
|
|
|
# pkgconfig
|
|
set(prefix ${CMAKE_INSTALL_PREFIX})
|
|
set(exec_prefix "\${prefix}")
|
|
set(libdir "\${exec_prefix}/lib")
|
|
set(includedir "\${prefix}/include")
|
|
configure_file(${CMAKE_CURRENT_SOURCE_DIR}/akerror.pc.in ${CMAKE_CURRENT_BINARY_DIR}/akerror.pc @ONLY)
|